【Excelマクロ】シンプルなカレンダーを作成【ユーザーフォーム】

Private Sub UserForm_Initialize() 'フォームが表示された時に実行
    'コンボボックスのリスト項目を追加
    For i = 1 To 12
        cbo月.AddItem i
    Next
    cbo週の始まり.AddItem "日"
    cbo週の始まり.AddItem "月"
    
    'リスト以外は入力禁止
    For Each i In Me.Controls
        If TypeName(i) = "ComboBox" Then i.Style = fmStyleDropDownList
    Next
    
    '初期値を選択
    txt年.Value = Year(Now)
    cbo月.Value = Month(Now)
    cbo週の始まり.Value = "日"
End Sub
Private Sub txt年_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger) '年(テキストボックス)のキー操作で実行
    '数字だけが入力できるように、数字以外のアスキーを0にして操作を無効化
    If Not Chr(KeyAscii) Like "[0-9]" Then
        KeyAscii = 0
    End If
End Sub
Private Sub spn年_SpinUp() 'スピンボタンのクリック時に実行(上)
    If Not IsNumeric(txt年) Then Exit Sub
    txt年 = txt年 + 1
End Sub
Private Sub spn年_SpinDown() 'スピンボタンのクリック時に実行(下)
    If Not IsNumeric(txt年) Then Exit Sub
    txt年 = txt年 - 1
End Sub
Private Sub cmd決定_Click() '決定ボタンで実行
    '年への文字列貼付とDate型エラー対策
    If IsNumeric(txt年) And txt年 > 99 And txt年 < 10000 Then
        Call modカレンダー作成.新しいシートへ作成
        Call modカレンダー作成.デザイン変更
        Unload Me
    Else '正しい値でない場合はメッセージ表示
        MsgBox "年は100以上9999以下の数字にしてください"
        txt年.SetFocus
    End If
End Sub

Weekday(DateSerial(.txt年, .cbo月, 1), 週の始まり)

Sub フォームを開く()
    frm年月入力.Show
End Sub
Sub 新しいシートへ作成()
    Sheets.Add(After:=ActiveSheet).Select '新シート追加
    
    'フォームのコントロールの値を参照してカレンダーを作成
    With frm年月入力
        '表題を入力
        Range("A1").Value = .txt年 & "年"
        Range("D1").Value = .cbo月 & "月"
        
        '週の始まりで入力位置をずらすための変数を記述
        Dim 週の始まり
        If frm年月入力.cbo週の始まり = "日" Then 週の始まり = vbSunday
        If frm年月入力.cbo週の始まり = "月" Then 週の始まり = vbMonday
        
        '曜日欄と日付を入力
        For i = 1 To 7 '曜日欄
            Cells(2, i) = WeekdayName(i, True, 週の始まり)
        Next
        For i = 1 To Day(DateSerial(.txt年, .cbo月 + 1, 0)) '日付
            Range("A3:G8").Cells(Weekday(DateSerial(.txt年, .cbo月, 1), 週の始まり) + i - 1) = i
        Next
    End With
End Sub
Sub デザイン変更()
    '月が一番目立つように
    With Range("D1")
        .Font.Size = 28 'フォントサイズ
        .Font.Bold = True '太字
    End With
    
    '曜日がわかりやすいように、曜日欄の色を変更
    For Each i In Range("A2:G2")
        Select Case i
            Case "日"
                i.Interior.Color = rgbCoral '赤
            Case "土"
                i.Interior.Color = rgbSkyBlue '青
            Case Else
                i.Interior.Color = rgbSilver '灰色
        End Select
        i.Font.Color = vbWhite '文字色を白に
        i.Font.Bold = True '太字
    Next
    
    '日付欄を罫線で区切り、文字を寄せて余白を作成
    With Range("A2", Cells(Range("A1").CurrentRegion.Rows.Count, 7)) 'A2から最終セル
        .Borders.LineStyle = xlContinuous '罫線を引く
        .RowHeight = 54 'セルの高さ
        .VerticalAlignment = xlTop '文字の縦位置を上詰めに
    End With
    
    'ほかの調整
    Range("A1:G1").BorderAround LineStyle:=xlContinuous '表題を罫線で囲む
    Range("A1").CurrentRegion.HorizontalAlignment = xlCenter '全体の文字の横位置を水平揃えに
End Sub